Open Text RightFax 10.6 installer for SMS/SCCM/Automated deployment

Open Text still has not figured out how to write a proper installer that installs all prerequisites for their product.

RightFax 10.5 required Microsoft .NET Framework 4.0.
Rightfax 10.6 requires Microsoft .NET Framework 4.5.

Even though it is included in the installation bundle AND the installer does a .NET version detection check, neither is installed by the respective RightFax installer (but the installer has NO problems complaining about the fact that the necessary version of .NET is not installed).

The Rightfax uninstaller doesn't actually uninstall everything that it needs to.

According to OpenText, you HAVE to reboot to 'properly' uninstall, so you can reinstall the same version, or install a newer version. There is no upgrade installation.

The installer also does a check for Visual C++ 2008, 2010 and 2012, but at least has the common decency to properly install these as necessary (installer located in the "prereqs" folder)

But, there are ways around vendor limitations (especially those that don't seem to care about enterprise environments, though they sell their products as such)

Folder structure of the installer:

• Root of installation folder
  

• "Prereqs" folder (Prerequisites)
  

To update from 9.40 to 10.6, the following has to occur (all without a reboot):

• Uninstall RightFax 9.40
• Install .NET Framework 4.5
• Install VC++ 2008
• Install VC++ 2010
• Install VC++ 2012
• Install RightFax 10.6

The RightFax installer cannot uninstall or upgrade older versions, so I had to find the Uninstall GUID for RightFax 9.40 which is located in the Registry (HKLM/Software/Wow6432Node/Microsoft/Windows/Current Version/Uninstall).

Note: you have to kill the running applications tied to RightFax prior to avoid the .MSI install failing.

taskkill.exe /F /IM FaxCtrl.exe /T
taskkill.exe /F /IM FaxUtil.exe /T
taskkill.exe /F /IM fuw32.exe /T
MsiExec.exe /X "{E60146B0-C083-47BE-BD6B-EFA57AC8D9B1}" /qn REBOOT=ReallySuppress RUNBYRIGHTFAXSETUP=2 CONFIGUREFAXUTIL=2 CONFIGUREFAXCTRL=2
MsiExec.exe /X "{F92CEDDB-2009-4039-88A6-CF0D85D31F21}" /qn REBOOT=ReallySuppress RUNBYRIGHTFAXSETUP=2 CONFIGUREFAXUTIL=2 CONFIGUREFAXCTRL=2

In addition, all remnants of the RightFax installation must be removed (files, folders, registry entries, etc.) otherwise the installation of a new(er) version might fail thinking that RightFax is currently installed:

CACLS "%ProgramFiles(x86)%\RightFax" /T /E /G Everyone:F
CACLS "%ProgramFiles%\RightFax" /T /E /G Everyone:F
RD /S /Q "%PROGRAMFILES(x86)%\RightFax"
RD /S /Q "%PROGRAMFILES%\RightFax"
REG.EXE IMPORT "%~dp0remove_rightfax.reg"

The above .reg file contains the following:

Windows Registry Editor Version 5.00
[-HKEY_LOCAL_MACHINE\SOFTWARE\RightFax]
[-HKEY_LOCAL_MACHINE\SOFTWARE\RightFax Client]
[-HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\RightFax]
[-HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\RightFax Client]
[-HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{E60146B0-C083-47BE-BD6B-EFA57AC8D9B1}]
[-HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{B60C695C-EF2F-4826-9106-417ED7A68658}]
[-HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{F41CD3A2-892D-4432-9941-3E483E43E7B2}]
[-HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{3E5E538D-D4B8-4553-860A-B09419F648BF}]
[-HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{73A00387-A686-4EDF-B3FF-6814AC41FD13}]
[-HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{C9CE2055-FD42-403F-B478-2E633BE1C9A6}]
[-HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{F92CEDDB-2009-4039-88A6-CF0D85D31F21}]
[-HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\{E60146B0-C083-47BE-BD6B-EFA57AC8D9B1}]
[-HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\{B60C695C-EF2F-4826-9106-417ED7A68658}]
[-HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\{F41CD3A2-892D-4432-9941-3E483E43E7B2}]
[-HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\{3E5E538D-D4B8-4553-860A-B09419F648BF}]
[-HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\{73A00387-A686-4EDF-B3FF-6814AC41FD13}]
[-HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\{C9CE2055-FD42-403F-B478-2E633BE1C9A6}]
[-HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Microsoft\Windows\CurrentVersion\Uninstall\{F92CEDDB-2009-4039-88A6-CF0D85D31F21}]

Since the RightFax installer does NOT install .NET Framework, this has to be manually scripted to be installed prior to installing the same version/newer version of RightFax:

dotnetfx45_full_x86_x64.exe /q /norestart

Install RightFax 10.6 using _setup.exe, since setup.exe has issues running correctly as SYSTEM via SCCM, and it will not wait until it has completed to kill the process. _setup.exe will wait. In addition, I just force install the prerequisites beforehand to cover my bases.

"%~dp0\Prereqs\VS2008_vcredist_x86.exe" /q
"%~dp0\Prereqs\VS2010_vcredist_x86.exe" /Q
"%~dp0\Prereqs\VS2012_vcredist_x86.exe" /install /quiet /norestart

My Entire Uninstall, PreReqs, Install script:

@ECHO OFF
SET COMPANY=Open Text, Inc.
SET NAME=RightFax
SET VERSION=10.6.0.2001 SR2
TITLE Installing %COMPANY% %NAME% %VERSION%
COLOR 4F

cd %~dp0
pushd %~dp0
CLS

:UNINSTALL_RIGHTFAX
:: Kill RightFax processes
@ECHO OFF
taskkill.exe /F /IM FaxCtrl.exe /T
taskkill.exe /F /IM FaxUtil.exe /T
taskkill.exe /F /IM fuw32.exe /T
CLS

@ECHO Currently removing existing installation of %NAME%.
@ECHO.
@ECHO (Do not close this window. The process may take 5 to 15 minutes to complete)
@ECHO OFF

:: Removing RightFax Client
:: 9.40
MsiExec.exe /X "{E60146B0-C083-47BE-BD6B-EFA57AC8D9B1}" /qn REBOOT=ReallySuppress RUNBYRIGHTFAXSETUP=2 CONFIGUREFAXUTIL=2 CONFIGUREFAXCTRL=2
MsiExec.exe /X "{F92CEDDB-2009-4039-88A6-CF0D85D31F21}" /qn REBOOT=ReallySuppress RUNBYRIGHTFAXSETUP=2 CONFIGUREFAXUTIL=2 CONFIGUREFAXCTRL=2
:: 10.5
MsiExec.exe /X "{B60C695C-EF2F-4826-9106-417ED7A68658" /qn REBOOT=ReallySuppress RUNBYRIGHTFAXSETUP=2 CONFIGUREFAXUTIL=2 CONFIGUREFAXCTRL=2
MsiExec.exe /X "{F41CD3A2-892D-4432-9941-3E483E43E7B2}" /qn REBOOT=ReallySuppress RUNBYRIGHTFAXSETUP=2 CONFIGUREFAXUTIL=2 CONFIGUREFAXCTRL=2
:: 10.6
MsiExec.exe /X "{C9CE2055-FD42-403F-B478-2E633BE1C9A6}" /qn REBOOT=ReallySuppress RUNBYRIGHTFAXSETUP=2 CONFIGUREFAXUTIL=2 CONFIGUREFAXCTRL=2

:: Removing Print Driver
MsiExec.exe /X "{73A00387-A686-4EDF-B3FF-6814AC41FD13}" /qn REBOOT=ReallySuppress RUNBYRIGHTFAXSETUP=2

@ECHO OFF
CACLS "%ProgramFiles(x86)%\RightFax" /T /E /G Everyone:F
CACLS "%ProgramFiles%\RightFax" /T /E /G Everyone:F

@ECHO OFF
RD /S /Q "%PROGRAMFILES(x86)%\RightFax"
RD /S /Q "%PROGRAMFILES%\RightFax"
REG.EXE IMPORT "%~dp0remove_rightfax.reg"

:INSTALL_DOTNET45
CLS
@ECHO Installing Microsoft .NET Framework 4.5...
@ECHO.
@ECHO (Do not close this window. The process may take 5 to 15 minutes to complete)
@ECHO OFF
"%~dp0\Prereqs\dotNetFx45_Full_x86_x64.exe" /q /norestart

:INSTALL_PREREQS
:: Install Visual C++ 2008 Redistributable 9.0.30729.17
"%~dp0\Prereqs\VS2008_vcredist_x86.exe" /q
:: Install Visual C++ 2010 Redistributable 10.0.40219
"%~dp0\Prereqs\VS2010_vcredist_x86.exe" /Q
:: Install Visual C++ 2012 Redistributable 11.0.60610
"%~dp0\Prereqs\VS2012_vcredist_x86.exe" /install /quiet /norestart

:INSTALL_RIGHTFAX
CLS
@ECHO Installing %COMPANY% %NAME%...
@ECHO.
@ECHO (Please be patient. The process may take 5 to 20 minutes to complete)
@ECHO OFF
"_setup.exe" /quiet=true /allowShutdown=true /add="FaxUtil,FaxCtrl" /rightFaxServer="server.contoso.com"